Print

Please login or register.
1 Hour 1 Day 1 Week 1 Month Forever
Login with username, password and session length

[jmone]

Background:  At the moment there is no way of playing Blu-ray or HD-DVD disks in MC12 especially for us Remote Control TheaterView users!  While the good folk at JR work on adding this feature here is a workaround I've got going on my HTPC (Shuttle SG33G5, inbuilt G33 graphics Quad Core, 2GB, Vista-32Bit, HDMI & S'PDIF Output, MCE Remote Control, & LG Blu-ray / HD-DVD combo drive) I thought I would share.  Caveat Emptor - While it works for me you are going to have to have to edit the script to get it working the way you want.

What it does:  It is pretty simple (now I've got it working). 
1) When you insert a Blu-ray HD-DVD disk / mount an ISO (when Autoplay is set to PowerDVD for these) or you select the "Blu-ray & HD-DVD" MC TheaterView button, it:
     - Closes MC12 (it's alright it will come back later but it frees up resources that was causing stuttering on my system)
     - Sets the graphics card to 24hz (note most Blu-ray & HD-DVD are in 1080p/24 so this helps avoid judder IF your TV and Graphics card supports 24hz or a multiple of this)
     - Moves the mouse off the right hand side of the screen (some bug in PowerDVD leaves the mouse visible sometimes....)
2) Just like with DVD Playback, when you press the "STOP" button on your Remote Control you end up back in MC TheaterView, as it:
     - Closes PowerDVD
     - Sets the graphics card back to 50hz (or 60Hz for you NTSC types)
     - Runs MC12

Requirements:  Your going to need to have installed and working in their own right:
1) Blu-ray / HD-DVD Player (eg LG's new combo drive is under US$300)
2) Cyberlink PowerDVD HD (comes with the LG drive but you need to do the free upgrade over the web to get it to work)
3) AutoHotkey ( http://www.autohotkey.com/ this is a freebie scripting app that does all the work, there will be others apps like Girder but you will need to create your own script)
4) JR Media Center 12 of course!

What you need to do:  Here is how to configure the lot to work together:
1) In MC12 "Tools --> Options --> Theaterview --> Add (Items To Show) --> Custom Items" and in the three fields enter: Name:Blu-ray & HD-DVD  Type:Program  Parameter:"C:\Program Files\CyberLink\PowerDVD\PowerDVD.exe" d: (note: including the ", the path for your PowerDVD install and the drive letter that is your Blu-ray / HD-DVD Drive)
2) Add AutoHotKey to your startup folder (it needs to run when Windows Boots up or nothing will happen)
3) Edit (to suit your needs) and add the script from below (or use it to replace) AutoHotKey's default AutoHotkey.ahk replacing all the standard stuff in that file.  Now this is where you need to be careful especially that you specify resolutions and refresh rates that you equipment support (Monitor/TV, Graphics Card etc) - make sure it works as the script will try to force your settings and I've read that you can apparently damage equipment that does not support it.  Also there is no "reverting in 15-Sec routine".  To help, look for the you can change to suit your requirements comments in the script.  If you don't want to make any changes to refresh rates at the moment OR your equipment dislikes having the refresh rate changed on it (I had a older plasma that used to object) then you should change the variables in both sections to that of your current video settings (that way nothing will happen).

Good Luck and here is hoping that the JR Lads have inbuilt Blu-ray / HD-DVD support soon!
Nathan

Code: [Select]

; ========================================================
; JR Media Center 12 TheaterView Integration Script for PowerDVD BluRay / HD-DVD playback
; --------------------------------------------------------
; The following script will detect if PowerDVD starts up
; --------------------------------------------------------

#NoTrayIcon
#Persistent
#SingleInstance, Force

TargetWindow = CyberLink PowerDVD ;- you can change to suit your requirments

Gui,+LastFound
hWnd := WinExist()
DllCall( "RegisterShellHookWindow", UInt,hWnd )
MsgNum := DllCall( "RegisterWindowMessage", Str,"SHELLHOOK" )
OnMessage( MsgNum, "ShellMessages" )
return

ShellMessages( wParam,lParam )
{
   ;Local k
   global
   If (wParam = 1)
   {
      NewID := lParam
      WinGetTitle, Title, ahk_id %NewID%
      WinGetClass, Class, ahk_id %NewID%
      If Title =
      {
         sleep 2000
          WinGetTitle, Title, ahk_id %NewID%
          WinGetClass, Class, ahk_id %NewID%
      }
        If Title = %TargetWindow%
          gosub ActionLabel
      return 1
    }
}

; --------------------------------------------------------
; The following script will run when PowerDVD Starts up and then will close MC12, Set Freq to 24hz and "Hides" the mouse
; --------------------------------------------------------
ActionLabel:
cD = 32   ; bits (quality) - you can change to suit your requirments
sW = 1920 ; pixels - you can change to suit your requirments
sH = 1080  ; pixels - you can change to suit your requirments
rR = 24   ; Hz (frequency) - you can change to suit your requirments

ChangeDisplaySettings( cD, sW, sH, rR )
Run MC12.exe /close
Mousemove 4000,0
return


; --------------------------------------------------------
; The following script will (if PowerDVD is running) Close PowerDVD, Set Freq back to 50hz, Run MC12 when the MCE "Stop" button is pressed
; --------------------------------------------------------
#IfWinExist CyberLink PowerDVD 
Media_Stop::  ; This is the STOP button (Media_Stop) - you can change to suit your requirments
WinActivate
WinClose

cD = 32   ; bits (quality) - you can change to suit your requirments
sW = 1920 ; pixels - you can change to suit your requirments
sH = 1080  ; pixels - you can change to suit your requirments
rR = 50   ; Hz (frequency) - you can change to suit your requirments

ChangeDisplaySettings( cD, sW, sH, rR )
Run C:\Program Files\J River\Media Center 12\Media Center 12.exe
return

; --------------------------------------------------------
; The script that makes the DLL Call to change the resolution - Don't Change
; --------------------------------------------------------

ChangeDisplaySettings( cD, sW, sH, rR ) {
  VarSetCapacity(dM,156,0), NumPut(156,2,&dM,36)
  DllCall( "EnumDisplaySettings", UInt,0, UInt,-1, UInt,&dM ), NumPut(0x5c0000,dM,40)
  NumPut(cD,dM,104),  NumPut(sW,dM,108),  NumPut(sH,dM,112),  NumPut(rR,dM,120)
  Return DllCall( "ChangeDisplaySettings", UInt,&dM, UInt,0 )
} 

; --------------------------------------------------------
; Credit to shimanov and Skan for the ChangeDisplaySetting script - see http://www.autohotkey.com/forum/viewtopic.php?t=8355
; Credit to Conquer for the script to monitor for PowerDVD's startup - see http://www.autohotkey.com/forum/viewtopic.php?t=26429
; --------------------------------------------------------


[richard.e.morton]

cool. well done.

[Matt]

I've been considering getting the same LG combo drive for home.

It's still so messy though.

I bought a 24" monitor a month ago that isn't HDCP (it was cheap, and had a good panel).  That means I need AnyDVD HD, which is like $130.  There's also no guarantee that AnyDVD will keep working as it is doing something they don't want me doing.

I also watch movies (from the same computer) in two other places.  Only one of those places is HDCP-compliant.

On top of that, it looks like filter makers like PowerDVD aren't letting their filters be used outside of their player, so JRiver Media Center, Windows Media Center, ZoomPlayer, etc. are out of luck for the time being.

This is an area JRiver would like to help with, but some obstacles like dueling formats and HDCP are out of our control.

[jmone]

Get a drive I say as the cost in time to get it going has been worse than the $'s!!  The drive itself is nice and easy to install and get going (SATA), but the bundled freebie version of PowerDVD is ordinary and will not work till you upgrade to online to a later verion (or buy the full version).  There are a range of freeware tools that will let you rip the content to your HDD where you can then either:
1) play the movie files (as per other post)
2) try to play from the HDD in a folder structure and play with one of the Blu-ray / HD-DVD players (only certain older versions of PowerDVD let you do this) or
3) create as an ISO, mount and play with one of the Blu-ray / HD-DVD players

You should be able to do any of the above HDCP free as the content has had AACS removed.  Tools like AnyDVD HD (which was US$65 running up till the end of the year, 20% discount + was in US$ not Euro) will fix the problem of playing the acutal disks without HDCP (which I need as while my G33 HDMI chipset is HDCP compliant, PowerDVD have not put it on their supported list so will refuse to play otherwise!)

Apart from the AACS limitations, I'm sure we will end up being able to play these disks from available filters at some point from within 3rd party media players OR that they will start to sell a "plug-in" designed to work with the likes of MS Media Center that we will be able to use.

Anyway for the most part I'm reasonably happy (and FYI the WAF / KAF is high) of the semi-integrated playback with Theater View / PowerDVD for the playback of these disks, and If I want to store a 30GB copy of the main movie on my HTPC I can also do that and playback nativly in MC12 just like anyother movie file....

Thanks
Nathan

[Osho]

I am very glad I ran into this information. This should be in J River Wiki.

I am in the exact same boat as jmone - I am planning to get a TV with native 24p support and upgrading my HTPC to play Blu-ray. But, all the software setting currently seems like it would be a royal pain to get the native 24p Blu-ray playback - unless I ran into this thread. This sounds like "usable" with a remote control.

Is there any plan to support Blu-ray playback in MC12? If so, please please think of refresh management as part of that implementation. Ideally, we should be able to figure out if we need to switch to 24Hz (or multiple - if supported) automatically and the refresh rate should change automatically. It should also automatically change back to whatever it was when Video playback is stopped. Is this doable at all?

I wonder how do the the stand-alone Blu-ray players etc. do. I also wonder if driving the display at 24p will also improve the DVD playback???

Osho

[raym]

...please please think of refresh management .... should be able to figure out if we need to switch to 24Hz (or multiple - if supported) automatically and the refresh rate should change automatically. It should also automatically change back to whatever it was when Video playback is stopped.

This is one of my biggest "wishes" for MC. Exactly as you've described and for all video types - Blue Ray, DVD, AVIs, whatever. I'm assuming it's exactly what hardware players do so I'd like to think it's doable.

This would be really slick. 

[Matt]

If you use MC12.exe /MonitorSwitch, are you able to get to the refresh rate you want?

I'm asking because if that works, it means we have the building blocks to do this.

[Matt]

Also, I'm curious, is there any real advantage to running at 24 instead of 60 Hz for Blu-ray?

The Nyquist theorem would suggest it shouldn't matter, and Blu-ray plays great for me at 60 Hz.  Also, does an LCD panel even change anything when you run at a different refresh, or does it just resample to its native rate regardless?

[raym]

If you use MC12.exe /MonitorSwitch, are you able to get to the refresh rate you want?

I'm asking because if that works, it means we have the building blocks to do this.

I didn't even know about this switch! I can't test this right now but I will later.... As long as it allows me to set the refresh rate and not just the resolution I guess we're looking good...

I'll leave the BlueRay questions to the guys who actually have a BlueRay player but in terms of my LCD TV, it will accept both 25hz and 30Hz signals at 1920x1080 depending on what I "feed" it. I can confirm this via its on screen menu and it does not resample as far as I'm aware. By default and for all my PAL movies, my video card's refresh rate is locked to 25hz but for my NTSC vids, I need to manually switch to 30hz. This is absolutely neccessary because I get really bad "judder" if the video refresh rates don't match the video source - ie, mutliples of 25 (hz) for PAL and 30 for NTSC.

If MC has the appropriate "building blocks" what would be great is if it provided and option to auto switch the video refresh rate to suite the movie being played (and then back to the default once playback stops).

[jmone]

Also, I'm curious, is there any real advantage to running at 24 instead of 60 Hz for Blu-ray? The Nyquist theorem would suggest it shouldn't matter, and Blu-ray plays great for me at 60 Hz.

  I'm going to give the whole debate about what what disks are encoded at 24p Vs 23.976p and if they look better or worse on Monitors/TV's running at 24hz or 60hz.  OK I lied, I bet the 24p disks look best at 24hz and the 23.976 disks at 60hz - but on my TV & HTPC system where I could run it at 24, 25, 30, 50, or 60hz at present I am happy with 60hz for my Blu-ray and HD-DVD disks (I don't think it is as smooth as 24hz but it was better than getting a jitter every 17sec - but that is another story and could be poor 23.976 handling on a 24hz output!). 

Also, does an LCD panel even change anything when you run at a different refresh, or does it just resample to its native rate regardless

.  I spoke to an ISF Calibrator about this (I've got a Pio Kuro 60" 1080p Plasma) and on my TV it will accept a 24/50/60hz refresh rate and adjust its display to that or a whole multiple of it.

The problem for us in PAL land is not getting 24p material to look good at 60hz, it is the shocking judder watching either 24, 30, or 60hz material on a 50hz screen - so we need to be able to tag what:
1) Our default refresh rate should be (eg 50hz for us PALers) and then
2) Tag different media files and disks to change the refresh rate to either 24/60hz when playing then
3) Revert it back to our default refresh rate (eg 50hz)

Thanks
Nathan

PS Unfortunatly I will not get to play with the /MonitorSwitch option till the end of Easter Hols!

[raym]

The problem for us in PAL land is not getting 24p material to look good at 60hz, it is the shocking judder watching either 24, 30, or 60hz material on a 50hz screen - so we need to be able to tag what:
1) Our default refresh rate should be (eg 50hz for us PALers) and then
2) Tag different media files and disks to change the refresh rate to either 24/60hz when playing then
3) Revert it back to our default refresh rate (eg 50hz)

Hey jmone, tagging is a good idea but don't you think it would be better if MC did the switching automatically if possible? For example, perhaps it could check the tag first and if it's not present, then take an educated guess? I'm also thinking of users with non-ripped content (DVD discs - remember them?) where library tags would be non-existent.

Cheers.

[jmone]

It would be ideal if MC could determine what frame rate the media was encoded at then change the Freq to suit, even if it was just between 50 and 60hz but I don't know if you can automagically determine this when opening a media file, dvd rip, dvd, blu-ray etc etc.
Thanks
Nathan

[Osho]

The Nyquist theorem would suggest it shouldn't matter, and Blu-ray plays great for me at 60 Hz.

I believe that the Nyquist sampling theorem will not apply in this case because the original data is actually 24Hz and not of higher sampling rate. It is "packaged" inside a 60Hz data but a good video processing engine should be able to extract the original 24Hz signal from it. Suppose you have a 24Hz signal

1920x1080 frame1
1920x1080 frame2
...
...
...
1920x1080 frame24

As I understand, Blu-ray format "packages" this in 1080i@60Hz signal as

1920x540 frame1_even
1920x540 frame1_odd
1920x540 frame2_even
1920x540 frame2_even
1920x540 frame2_odd
....
...
...

Theoretically, one would get a "movie-like" smooth playback of the original signal if

• the video processing engine was smart enough to extract the original 24Hz signal from this
• the video graphics card was able to output 24Hz (or multiple of it) signal
• the TV was able to accept a 24Hz (or multiple of it) signal *and* display it at that frequency without internally transferring to 60Hz or other rate

Also, does an LCD panel even change anything when you run at a different refresh, or does it just resample to its native rate regardless?

I think this depends on the LCD or plasma panel. There are some TVs that are capable of taking 24Hz (or multiple of it) input and displaying it at that frequency. I don't have a TV capable of 24Hz refresh capability yet but I am planning to buy Panasonic TH-50PZ800U later this spring when it is released. One of the main reason why I want to buy this TV is its capability to take a 24Hz input signal and display it at 24Hz. And, I would like to setup MC12+PowerDVD-engine combination such that the switch to 24Hz output happens "auto-magically".

Osho

[jmone]

If you use MC12.exe /MonitorSwitch, are you able to get to the refresh rate you want?

I'm asking because if that works, it means we have the building blocks to do this.

It seems to work!  I've used "C:\Windows\System32\MC12.exe /MonitorSwitch 0:1920x1080x32x60" and "C:\Windows\System32\MC12.exe /MonitorSwitch 0:1920x1080x32x50" to change between 50 and 60hz just fine.

Thanks
Nathan

[jmone]

Blu-ray / HD-DVD ISO's in MC12 - Using the method described in http://wiki.jrmediacenter.com/index.php/DVD_Library_in_Media_Center#ISO_file you can also import and manage Blu-ray & HD-DVD ISO's rips in MC12 which will then mount and play (after a pause) using the script described in the first post.
Thanks
Nathan

[jmone]

Here is an updated script that supports Arcsoft's TMT as well as PowerDVD.....I've changed to TMT as PowerDVD has dropped HD-DVD support in V8.

Code: [Select]

; ========================================================
; JR Media Center 12 TheaterView Integration Script for PowerDVD or Total Media Theatre BluRay / HD-DVD playback
; --------------------------------------------------------
; The following script will detect if PowerDVD / Total Media Theatre starts up
; --------------------------------------------------------

#NoTrayIcon
#Persistent
#SingleInstance, Force

TargetWindow1 = CyberLink PowerDVD 8.0 ;- you can change to suit your requirments
TargetWindow = ArcSoft TotalMedia Theatre ;- you can change to suit your requirments

Gui,+LastFound
hWnd := WinExist()
DllCall( "RegisterShellHookWindow", UInt,hWnd )
MsgNum := DllCall( "RegisterWindowMessage", Str,"SHELLHOOK" )
OnMessage( MsgNum, "ShellMessages" )
return

ShellMessages( wParam,lParam )
{
   ;Local k
   global
   If (wParam = 1)
   {
      NewID := lParam
      WinGetTitle, Title, ahk_id %NewID%
      WinGetClass, Class, ahk_id %NewID%
      If Title =
      {
         sleep 2000
          WinGetTitle, Title, ahk_id %NewID%
          WinGetClass, Class, ahk_id %NewID%
      }
        If Title = %TargetWindow%
          gosub ActionLabel
If Title = %TargetWindow1%
          gosub ActionLabel
      return 1
    }
}

; --------------------------------------------------------
; The following script will run when PowerDVD or Arcsoft TMT Starts up and then will close MC12, Set Freq to 24hz and "Hides" the mouse
; --------------------------------------------------------
ActionLabel:
cD = 32   ; bits (quality) - you can change to suit your requirments
sW = 1920 ; pixels - you can change to suit your requirments
sH = 1080  ; pixels - you can change to suit your requirments
rR = 60   ; Hz (frequency) - you can change to suit your requirments

ChangeDisplaySettings( cD, sW, sH, rR )
Run MC12.exe /close
Mousemove 4000,0
return


; --------------------------------------------------------
; The following script will (if PowerDVD is running) Close PowerDVD, Set Freq back to 50hz, Run MC12 when the MCE "Stop" button is pressed
; --------------------------------------------------------
#IfWinExist CyberLink PowerDVD 
Media_Stop::  ; This is the STOP button (Media_Stop) - you can change to suit your requirments

WinClose

Run C:\Program Files\J River\Media Center 12\Media Center 12.exe

cD = 32   ; bits (quality) - you can change to suit your requirments
sW = 1920 ; pixels - you can change to suit your requirments
sH = 1080  ; pixels - you can change to suit your requirments
rR = 50   ; Hz (frequency) - you can change to suit your requirments

ChangeDisplaySettings( cD, sW, sH, rR )

return

; --------------------------------------------------------
; The following script will (if Arcsoft TMT is running) Close TMT, Set Freq back to 50hz, Run MC12 when the MCE "Stop" button is pressed
; --------------------------------------------------------
#IfWinExist ArcSoft TotalMedia Theatre
Media_Stop::  ; This is the STOP button (Media_Stop) - you can change to suit your requirments

Run C:\Program Files\J River\Media Center 12\Media Center 12.exe

cD = 32   ; bits (quality) - you can change to suit your requirments
sW = 1920 ; pixels - you can change to suit your requirments
sH = 1080  ; pixels - you can change to suit your requirments
rR = 50   ; Hz (frequency) - you can change to suit your requirments

ChangeDisplaySettings( cD, sW, sH, rR )

Process, Close, uDigital Theatre.exe ; Needs to close the process as WinClose just minimises TMT
return

; --------------------------------------------------------
; The script that makes the DLL Call to change the resolution - Don't Change
; --------------------------------------------------------

ChangeDisplaySettings( cD, sW, sH, rR ) {
  VarSetCapacity(dM,156,0), NumPut(156,2,&dM,36)
  DllCall( "EnumDisplaySettings", UInt,0, UInt,-1, UInt,&dM ), NumPut(0x5c0000,dM,40)
  NumPut(cD,dM,104),  NumPut(sW,dM,108),  NumPut(sH,dM,112),  NumPut(rR,dM,120)
  Return DllCall( "ChangeDisplaySettings", UInt,&dM, UInt,0 )
} 

; --------------------------------------------------------
; Credit to shimanov and Skan for the ChangeDisplaySetting script - see http://www.autohotkey.com/forum/viewtopic.php?t=8355
; Credit to Conquer for the script to monitor for PowerDVD's startup - see http://www.autohotkey.com/forum/viewtopic.php?t=26429
; --------------------------------------------------------

[Donny Bahama]

This thread has made me VERY happy. Now that I know I can launch AHK scripts, I CAN CONQUER THE WORLD!!! MWAH HAHA HA HAAAAAA...