Print

Please login or register.
1 Hour 1 Day 1 Week 1 Month Forever
Login with username, password and session length

[lepa]

A newer thread is here:  https://yabb.jriver.com/interact/index.php/topic,135179.msg936142.html#msg936142

---------
In this thread you can discuss about custom Tooltips & TheaterView templates.

Image tag based icons:
Today MC also support image tag which is considerably easier to work with than using above font based imaging.
how to use:
<img src="filepath" width="nn" height="nn" valign="[top|middle|bottom]">

Font based icons:
(Kind of obsolete now days but still usable)
Thanks to Moe's media dedicated icons font it is now easy to display many kinds logos and icons related to audio / video. Moe has also collected icons for genres and created a font for that also

Download and install video and audio icons font from here
If you like genre icons download and install font from here
 
Scrape information from internet:
Graphical UI to fetch movie data, posters and personnel images:
 - ZRatings is here
CLI tool to do everything 
 - MCUtils is here


CUSTOM TOOLTIPS FOR DIFFERENT MEDIA TYPES:
Create new calculated fields so it is easier to customize different media types.
ref: https://yabb.jriver.com/interact/index.php/topic,135033.0.html

Tooltip examples:
 - Moe's Movie wonderfull tooltip: https://yabb.jriver.com/interact/index.php/topic,119385.msg837496.html#msg837496
 - My Movie tooltip: https://yabb.jriver.com/interact/index.php/topic,119385.msg825497.html#msg825497
 - zybex thread to collect tooltips: https://yabb.jriver.com/interact/index.php/topic,119874.0.html

THEATER VIEW MOVIE TEMPLATES
Attached to this post you can find my outdated movie template for theater view (both small and large views). You can try it by copying its contents to clipboard and using Tools >> Options >> Theater View >> Options >> ...Customize file info panel... >> Manage >> Add Template From Clipboard.

More hints how to copy paste theater view template: https://yabb.jriver.com/interact/index.php/topic,119385.msg840971.html#msg840971

In my screens I'm using 4K mode for Theater View UI with size value 80%. That is because MC doesn't support custom default font size and 80% gives me font size that works for me. If you are going to use different size values (bigger), you will need to change some font sizes in the items (at least for separator lines) in order to draw them correct.

Metadata has been fetched with MC,  MCUtils and MCRatings

 - Moe's Theater View screen: https://yabb.jriver.com/interact/index.php/topic,119385.msg838983.html#msg838983
 - Thorsten Movie Theater View and tooltip: https://yabb.jriver.com/interact/index.php/topic,119385.msg839927.html#msg839927
 - New MC30 Template using video file metadata import introduced in MC30.60. Stock fields should be enough to get going. ZRatings / MCUtils gives something extra like [IMDb Rating], [TMDB Rating], [Movie Series] etc LINK TO BE ADDED


THEATER VIEW TV SHOWS TEMPLATES
 - New "MC30 No Cover" Template using video file metadata import introduced in MC30.60. Stock fields should be enough to get going. MCUtils gives something extra like [TMDB Rating], [Guest Stars], series [Status] etc LINK TO BE ADDED

More examples and info can be found in this thread...

EDIT:
12.2.2023 Cleaned up an preparing for the MC 30.61 which introduces more video attributes scraping from the file
18.11.2022 Cleaned post a little some information might be outdated. Latest things are somewhere in latest posts in this tread. Don't have time to update first post always
21.8.2020 My new movie template here https://yabb.jriver.com/interact/index.php/topic,119385.msg877551.html#msg877551
15.3.2020 New "Movie-Template.txt". Images usage for icons and cast. Preview Image
29.7.2019 added info about size %, Added links for MCUtils and MCRatings
27.7. 2019 cleaned up a little
14.7.2019 updated movie template zip file
13.7.2019 Updated TheaterView TV Show large screen
11.7.2019 Updated TheaterView Audio image
10.7.2019 Added audio tooltip and theater view image
7.7.2019 with new screen template and preview image

[RoderickGI]

Ability to change font using html tags. It would enable us using fonts which have icons for bluray, dts etc.

Already there. See the image in this post for an example.

There are fonts with icons for Blu-ray, DTS, etc.? Please share.

[leezer3]

There are fonts with icons for Blu-ray, DTS, etc.? Please share.

Look into IcoMoon:
https://icomoon.io

Chromium engine would probably support it if the appropriate CSS could be injected somewhere.

[lepa]

Already there. See the image in this post for an example.

There are fonts with icons for Blu-ray, DTS, etc.? Please share.

Oh, I thought you could only change properties of the font set in the options. There is no URL in your link though..
I found DigitalSymbols named front which might have something usable. Don't remember anymore where did I get it but I think that it could be found with google

[swiv3d]

It's at
https://www.fontspace.com/snapefonts/digitalsymbols

[lepa]

Ok, if anyone else is wondering <font face=> works and you can dynamically change font with it. I don't know why I didn't it get to work in the first place when I tried it.

[lepa]

Played a little with this

Code: [Select]

If(IsEqual([Media Sub Type],Movie,1), <font size="200"><b>[Name]Delimit([Year],/),/# (#/)Delimit([Access Rating],/),/# (#/)<//b><//font> /[ <font color="#f69838">RatingStars() <//font>/]
<font face="ToolTip01" size="100" color="#9496a3">If(IsEqual([MPAA Rating],G),A,If(IsEqual([MPAA Rating],PG),B,If(IsEqual([MPAA Rating],PG-13),C,If(IsEqual([MPAA Rating],R),D,If(IsEqual([MPAA Rating],NC-17),E,If(IsEqual([MPAA Rating],NR),<//font><font face="ToolTip01" size="80" color="#9496a3">F,))))))   <//font><font color="#9496a3" size="100"><b>|<//b><//font>   <font color="#9496a3" size="100">Size()   <b>|<//b><//font>   <font color="#9496a3" size="100"><i>Replace([Genre],;,  / // )<//i>   <b>|<//b>   [Date] /([Country]/)<//font>

If(IsEqual([Awards], Oscar, 8),If(IsEqual([Awards], Won, 8),<font face="ToolTip01" size="150" color="#b59031">4<//font> <font face="ToolTip01" size="300" color="#FFFF00">@  <//font>, <font face="ToolTip01" size="150" color="#b59031">4<//font> <font face="ToolTip01" size="300" color="#a6a6a6">@  <//font>),)<font size="150">If(!IsEmpty([Critic Rating]),<font face="ToolTip01" size="150"><font color="#01CB73">;<//font><//font>  [Critic Rating] ,) If(!IsEmpty([Rating IMDb]),<font face="ToolTip01" size="150"><font color="##E8B708">7<//font><//font>  [Rating IMDb] ,)  If(!IsEmpty([Rotten Tomatoes]),<font face="ToolTip01" size="150"><font color="#ED1C08">8<//font><//font>  [Rotten Tomatoes]% If(isequal([Rotten Tomatoes], , 0), , If(isequal([Rotten Tomatoes], 60, 6), <font face="ToolTip01" size="150"><font color="#F13008">:<//font><//font>,<font face="ToolTip01" size="150"><font color="#0FC152">9<//font><//font>)),)<//font>
____________________________________________________________________________________________________________________
If(!IsEmpty([Description]),<font size="115">[Description]<//font>,)

If(!IsEmpty([Keywords]),/(<i>[Keywords]<//i>/),)
____________________________________________________________________________________________________________________
If(!IsEmpty([Director]),<font size="120" color="#898989"><b>DIRECTOR:    <//b><//font><font color="#ffffff"><i>Replace([Director],;,  / // )<//i><//font>
,)If(!IsEmpty([Actors]),<font size="120" color="#898989"><b>STARS:          <//b><//font><font color="#ffffff"><i>Replace(ListLimit([Actors],5),;,  / // )<//i><//font>
,)If(!IsEmpty([Screenwriter]),<font size="120" color="#898989"><b>WRITER:       <//b><//font><font color="#ffffff"><i>Replace([Screenwriter],;,  / // )<//i><//font>
,)If(!IsEmpty([Screenwriter]),<font size="120" color="#898989"><b>PRODUCER:  <//b><//font><font color="#ffffff"><i>Replace([Producer],;,  / // )<//i><//font>

,)If(!IsEmpty([Budget]),<b>BUDGET:<//b> $Math(Trunc([Budget]/1000000,1)) Million  ,)If(!IsEmpty([Gross Revenue]),//  <b>GROSS REVENUE:<//b> $Math(Trunc([Gross Revenue]/1000000,1)) Million
,)If(!IsEmpty([Awards]), <b>AWARDS:<//b> <i>[Awards]<//i>
,)






____________________________________________________________________________________________________________________
<font face="ToolTip01" size="310" color="#9496a3">If(IsEqual([Width],1920,5),¥,If(IsEqual([Width],1360,5),¤,If(IsEqual([Width],888,5),£,If(IsEqual([FPS],25,2),¢,¡))))<//font>    <font face="ToolTip01" size="300" color="#9496a3">If(Math(Below(Trunc(Replace([Aspect Ratio],:,//) + .005, 2),1.38)),M, If(Math(Below(Trunc(Replace([Aspect Ratio],:,//) + .005, 2),1.68)),N,If(Math(Below(Trunc(Replace([Aspect Ratio],:,//) + .005, 2),1.80)),O,If(Math(Below(Trunc(Replace([Aspect Ratio],:,//) + .005, 2),1.87)),P,Q))))<//font>   <font face="ToolTip01" size="300" color="#9496a3">If(IsEqual([Channels],1,2),=,If(IsEqual([Channels],2,2),>,If(IsEqual([Channels],3,2),],If(IsEqual([Channels],4,2),?,If(IsEqual([Channels],5,2),^,If(IsEqual([Channels],6,2),‐,If(IsEqual([Channels],7,2),_,‑)))))))<//font>   <font face="ToolTip01" size="300" color="#9496a3">If(IsEqual([Compression],DTS,8),# ,If(IsEqual([Compression],AC3,8),z ,If(IsEqual([Compression],PCM,8),/) ,If(IsEqual([Compression],mp3,8),+ ,If(IsEqual([Compression],flac,8),/( ,If(IsEqual([Compression],aac,8),0 ,If(IsEqual([Compression],MPEG,8),à ,If(IsEqual([Compression],Vorbis,8),/ ,,))))))))<//font><font face="FilmStudios" size="200" color="#9496a3">If(IsEqual([Notes],Criterion Collection,8),w ,)If(IsEqual([Notes],Arrow,8),q ,)<//font><font face="FilmStudios" size="250" color="#9496a3">If(IsEqual([Production Companies],Century Fox,8),e ,)If(IsEqual([Production Companies],Buena Vista,8),y ,)If(IsEqual([Production Companies],Cannon,8),u ,)If(IsEqual([Production Companies],Castle Rock,8),i ,)If(IsEqual([Production Companies],Columbia,8),o ,)If(IsEqual([Production Companies],DC,8),p ,)If(IsEqual([Production Companies],DreamWorks,8),s ,)If(IsEqual([Production Companies],Gaumont,8),d ,)If(IsEqual([Production Companies],Golden Harvest,8),g ,)If(IsEqual([Production Companies],Imagine Entertainment,8),h ,)If(IsEqual([Production Companies],Jim Henson,8),j ,)If(IsEqual([Production Companies],Lionsgate,8),k ,)If(IsEqual([Production Companies],Lorimar,8),l ,)If(IsEqual([Production Companies],Lucasfilm,8),z ,)If(IsEqual([Production Companies],Marvel,8),c ,)If(IsEqual([Production Companies],Metro,8),b ,)If(IsEqual([Production Companies],Miramax,8),n ,)If(IsEqual([Production Companies],Morgan Creek,8),1 ,)If(IsEqual([Production Companies],New Line Cinema,8),3 ,)If(IsEqual([Production Companies],New World Pictures,8),4 ,)If(IsEqual([Production Companies],Orion,8),5 ,)If(IsEqual([Production Companies],Paramount,8),6 ,)If(IsEqual([Production Companies],Pathe,8),7 ,)If(IsEqual([Production Companies],Pixar,8),8 ,)If(IsEqual([Production Companies],Regency,8),0 ,)If(IsEqual([Production Companies],RKO,8),Q ,)If(IsEqual([Production Companies],RKO,8),E ,)If(IsEqual([Production Companies],Ghibli,8),R ,)If(IsEqual([Production Companies],StudioCanal,8),T ,)If(IsEqual([Production Companies],Touchstone,8),Y ,)If(IsEqual([Production Companies],Tristar,8),U ,)If(IsEqual([Production Companies],United Artists,8),I ,)If(IsEqual([Production Companies],Universal,8),O ,)If(IsEqual([Production Companies],Walt Disney,8),A ,)If(IsEqual([Production Companies],Warner Bros.,8),S ,)If(IsEqual([Production Companies],Virgin,8),D ,)<//font>
____________________________________________________________________________________________________________________
[Filename]

If(!IsEmpty(FilePlaylists()),Playlists:
  <b>FilePlaylists()<//b>,),)

[RoderickGI]

Very nice.

I've been meaning to play with this for some time, but never got to it. Maybe I will need to now that you've shown the way!

[Moe]

Played a little with this

Would you mind showing the code that you used to achieve this.  It would be nice to have a starting place rather than reinvent the wheel.  It looks great.

[lepa]

I've made some new calculated fields so it is easier to customize different media types
https://yabb.jriver.com/interact/index.php/topic,99227.0.html

[Tooltip] field calculation rule:

Code: [Select]

FirstNotEmpty([Tooltip - Movie], [Tooltip - TV Show], [Tooltip - Audio]) - You would only need [Tooltip - Movie] if you only want to customize movies

[Tooltip - Movie] field calculation rule:

Code: [Select]

If(IsEqual([Media Sub Type],Movie,1), <font size="150"><b>[Name]Delimit([Year],/),/# (#/)Delimit([Access Rating],/),/# (#/)<//b><//font> /[ <font color="#f69838">RatingStars() <//font>/]
<font size="130">TVInfo(SizeDisplay)   <b>||  <//b>If(!IsEmpty([Critic Rating]),<b>TMDb:<//b> <font color="#f69838">★[Critic Rating]<//font>,) If(!IsEmpty([Rating IMDb]),<b> | IMDb:<//b> <font color="#f69838">★[Rating IMDb]<//font>,)<b>  ||<//b>
If(!IsEmpty([Genre]),/(<i>[Genre]<//i>/)<//font>,)

<font face="DigitalSymbols" size="200">≤ If(IsEqual([MPAA Rating],G),ä,If(IsEqual([MPAA Rating],PG),ë,If(IsEqual([MPAA Rating],PG-13),ï,If(IsEqual([MPAA Rating],R),ö,If(IsEqual([MPAA Rating],NC-17),T,))))) If(IsEqual([Width],1920,5),<font face="Segoe UI" size="80"><b>⋐4K⋑<//b><//font>,If(IsEqual([Width],720,5),I,z)) ~<//font>
____________________________________________________________________________________________________________________
If(!IsEmpty([Description]),<font size="115">[Description]<//font>,)

If(!IsEmpty([Keywords]),/(<i>[Keywords]<//i>/),)
____________________________________________________________________________________________________________________
If(!IsEmpty([Director]),<b>Director:<//b> [Director]
,)If(!IsEmpty([Screenwriter]),<b>Screenwriter:<//b> [Screenwriter]
,)If(!IsEmpty([Actors]),<b>Actors:<//b> [MainActors]

,)If(!IsEmpty([Budget]),<b>Budget:<//b> $Math(trunc([Budget]/1000000,1)) Million  ,)If(!IsEmpty([Gross Revenue]),//  <b>Gross Revenue:<//b> $Math(trunc([Gross Revenue]/1000000,1)) Million
,)
____________________________________________________________________________________________________________________
[Filename]
Playlists: FilePlaylists(),) - Separator horizontal line length works for me with font size 9.
 - tmdb data is collected with MrC's perl script. For example actors are limited to five first credited persons and rating is number without tmdb prefix.
 - [Rating IMDb] is custom field
 - Bluray / DVD icons are calculated from resolution. This I would like to change so that, tv recordings, complete bluray/dvd, rips etc would identified and icon would be accordingly.
 - TODO: Aspect Ratio and Audio type icons are for now hard coded and not calculated

Maybe we should start a new threads to share Tooltips and TheaterView views so people can get new ideas how to enhance their interface. I at least have made most of my modifications by copying and altering other peoples work.

I think that this tooltip engine could be used also to make OSD info sheet much nicer looking.

[Moe]

Thank you so much!  Going to have to play around with this when I have a chance.

[Moe]

I finally got around to fooling around with this.  Love it.

Here are my results



Couple of things that I think are kind of cool.  The Oscar statue is gold if the movie won an Oscar, gray if it was only nominated.  The linked digitalsymbols font was great, but it was missing a few icons that I wanted.  It didn't have an MPAA rating thing for unrated movies.  It didn't have an icon for FLAC or MP3 audio streams and a few other things as well.  I was able to add some extra symbols to that font, I've uploaded it here

Big thanks to Lepa for the starting point and the tip for creating tooltips for the different media types!

[lepa]

Looking very good, Moe! Glad you decided to share and give us some new ideas and thanks for the updated font. I'm gonna look in to that. Was it hard to add new icons to a font? Did explore it bit but never actually got anything done. I was (am) missing truehd and dts-hd logos and also some other music related icons would be cool.

Found some icons from the eu-sym font

[Moe]

What I did with the font was very easy, but I (mostly) didn't design any icons myself.  I actually took some from that eu-sym font that you linked.  I used a free program called Birdfont to edit the font.  Birdfont allows you to open multiple instances at the same time.  So, what I did was open the DigitalSymbols font in one instance of Birdfont and then opened the font that I wanted to borrow other elements from in another instance of Birdfont.  From there it's as easy as copying and pasting the symbols you want from one font to another. 

I couldn't find a good existing font symbol for the FLAC logo.  I did a bit of research into making fonts and I found out that they are based off SVG files.  I found the flac logo in an SVG format and pasted that into Birdfont as a new character and it worked (kind of).  I mostly got lucky that it worked, this was the result. 



Looks good, but what I pasted in actually had the "Free Lossless Audio Codec" text on the bottom.  Additionally, the aspect ratio image was overlapping the FLAC logo.  I fixed that by adding some spaces to the expression (ć corresponds to the FLAC icon)

Code: [Select]

if(isequal([Compression],flac,8),ć       ,
I have a few more icons I'd like to find as well.  I'd like to find one for TMDb, IMDb and I'd love to find icons for the Rotten Tomatoes fresh and rotten reviews.

Maybe as a group we can make the ultimate font for tooltips.  Lepa, since you created this thread I wonder if it would be worthwhile to change the title of the thread to something about customizing the tooltip, may get some more eyeballs on the thread? 

[lepa]

Changed title. I think that I tried BirdFont but it was so terribly slow that I deleted it already. Maybe will try it again... So for videos at least true-hd and dts-hd ma is missing. Not sure if there was an icon for AC3.

What is the easiest way to preview fonts to see all the icons in it?

[Moe]

What is the easiest way to preview fonts to see all the icons in it?

I've mostly been using birdfont, it's a bit limited, because you can't always see the entire image if it's wide, but it's been serving it's purpose for me so far.  There is also freeware that allows you to preview.  I haven't used it, but I just found this via a quick google https://us.fontviewer.de/

I've been trying to get IMDB and Rotten Tomatoes icons going and I am making good progress.  I found this site https://icomoon.io/app/#/select which makes it really easy to convert an SVG file into a font.  The site does all the work for you.  I'll share my progress later, once I have something substantial to show, but it's looking really good (I have IMDB up and running).

If you can find an SVG file for true-hd and dts-hd I'd be happy to add it to my font.

I want to make a page on my website when all is said and done that shows all the icons in the font I am creating as well as the corresponding letter to generate the icon.  Should make doing this a lot easier.

[lepa]

Few ones which are missing:
Multicolor DTS-HD MA
https://commons.wikimedia.org/wiki/File:Dolby_TrueHD.svg
https://upload.wikimedia.org/wikipedia/commons/7/75/Opus_logo1.svg

aac?

Tried also to create mono logo with inkscape but could get it imported properly to font 

EDIT: Also it would be great if you could change position of some of the logos. At least that bluray disc and also matroska icons are upper on y scale than some others at least in the original digitalsymbols/eu-symbols

[Moe]

I made some progress, check out the bottom part of this tooltip



A couple of options for IMDB, Rotten Tomatoes logo, RT Rotten/Fresh logos, DTS HD, fixed the FLAC icon and Dolby TrueHD.

I'll get that Opus logo added and see about AAC.  What's the Mono logo? 

I found this site https://www.pngtosvg.com/ which will turn a PNG or Jpg into an SVG file.  I've been having really good luck with it.  Since fonts don't support multiple colors, if I find an image with multiple colors (the RT fresh icon is how I learned about all this as it is two colors) I open it up in Photoshop and turn it into a black and white image and then create the SVG from that image. 

Also it would be great if you could change position of some of the logos. At least that bluray disc and also matroska icons are upper on y scale than some others at least in the original digitalsymbols/eu-symbols

I haven't messed around with it much, but in Birdfont this should be very easy to do.  If you look at the icon in Birdfont you can adjust the margins (see the image below), they just drag to where you want.



While I am thinking about it, this is my workflow. 

1. Find an image that you want to turn into a font icon. 
2. If it's multiple color I open it up in Photoshop and turn it black and white
3. Go to https://www.pngtosvg.com/ and turn the image into a SVG file
4. Go to https://icomoon.io/app/#/select and press "Import Icons" in the top left corner and then select the SVG file generated in step 3
5. Still on icomoon.io at the bottom of the page click "Generate Font" and then "Download"
6. At this point you have a font with your new icons.  I then open up my master (DigitalSymbols3) font in one instance of Birdfont and the newly created font created in step 5 in another instance of Birdfont.
7. Copy and paste from the new font into the master font in Birdfont
8. Export the update font from Birdfont and install it.

[lepa]

Very cool. I like especially yellow icon for imdb. It seems that MC just scales the font instead of using bigger size so when using bigger icons the edges gets jagged.

What's the Mono logo? 

There were icons for stereo and 5.1 surround so tried to do the mono icon in the same style.

Thanks for sharing and I think that I will try also learn font/svg stuff by replicating your workflow


EDIT: was searching for musepack logo and found at least one aac icon in jpeg format http://www7a.biglobe.ne.jp/~fortywinks/image/logo/aac.jpg

[Moe]

I'm in the middle of a big font update.  If you have any requests, now is the time to make them.

I am going to add the icons like your mono one for 5.1, 7.1, etc.  Already have your Opus one and ACC

[Moe]

Okay, I think I'm ready to share the font that I've been working.  I also found a great WordPress plugin that lets you view the font very easily

Here is what I have so far, I omitted a bunch from the original DigitalSymbols font, I didn't think we needed recycling icons or 30 different compact disc icons.  There are some things that I plan on adding back in, like the TV ratings (including for the different regions) and some other odds and ends.  But I think this is a good starting place. 

I am happy to take requests as well.  It's pretty easy to add new ones once you wrap your head around it all.

Here is a sneak peek



And here is the link where you can play around with it

https://moesrealm.com/MC/mc-tooltip/

There are sliders to resize and whatnot on the page as well.

(lepa, I nudged one of the Blu-Ray Disc icons down for you too)

[lepa]

That looks GREAT. Thanks also for getting rid of useless icons.
Might be useful still to add some icons for file type containers like e.g. matroska/mp4/avi/mpeg/ts (ifo/iso could then be uhd/bluray/dvd) and for dimensions e.g. 4K, HD (1080p, 720p), SD.

Now I just need some time to tune tooltips 

I've also experimented with the TheaterView but have still not figured out how to setup logos so that they look good and integrated to other components.

I still think that it would be great if tooltip engine could be utilized to create also some fancy OSD info overlay look.

[JimH]

Nice work!  Thanks for sharing!

[lepa]

TMDb icon to accompany that square IMDb logo:
https://www.themoviedb.org/assets/2/v4/logos/stacked-blue-5cd9d4be255c92e26c4a6c7722a66a7b636abaf8b0f3d7b44cbb26c6dcee605d.svg

[Moe]

I'll add the TMDB square one.  I am currently collecting 4K, 1080P, etc logos per your request.

[Moe]

I updated the set. I got the square TMDB icon, a bunch of file type icons (I am not crazy about them, but they work and there are a few options), SD/HD/4k etc type icons and the MKV one.  I also added a download link, which I forgot last night

https://moesrealm.com/MC/mc-tooltip/

[lepa]

Thanks a lot Moe! Looking pretty awesome! Not a big deal for me but as someone in the PAL land perhaps there could be also 576p which was SD resolution here.

Anyway thanks for your work on the font. Hopefully others will also pick up tool tip tuning and we get more ideas here to steal 

[Moe]

Another small update.  I added a couple 576 icons.  Also fixed the sizing of some of the characters.  I was wondering why some were appearing so small, it took awhile but I figured it out.  Should anyone try and use the https://icomoon.io/app/#/select tool to convert to a font.  If you have icons of varying width, do them in separate batches.  It seems that when you do a bulk upload the program makes them all a uniform width and doesn't default to the largest.

https://moesrealm.com/MC/mc-tooltip/

EDIT:  I have now added all the rating icons that were in the original font and other odds and ends as well.  I think that's about it for now.  Happy to take requests though.

[Moe]

Here's the fruits of my labor, pretty happy with it!



Now to do TV shows and music 

[lepa]

Not bad (Meaning very good in finnish )

One idea what I get from looking the image is that have you tried to put that oscar statue in the same row as ratings? It would perhaps catch eye better there and also logically groups to ratings quite well. Anyway just an idea.

I'm not so satisfied to my own template at this time so nothing to show for now...

[BryanC]

I'd love to see these icons integrated into MC by default, they look great!

[Moe]

Excellent idea lepa!  I may brighten the font a bit, but this does look much better.

[lepa]

I'd love to see these icons integrated into MC by default, they look great!

There might be some copyright issues when companies are involved

And Moe, I might steal your Iron Man icon-row-flow  Is "oscars" text one character or some different font?

[Moe]

The "Oscars" is a new symbol in the font (It corresponds to the number 4).  I just updated the site so you should see it on there now.  I was running out the door to get to work so I didn't have time this morning.

https://moesrealm.com/MC/ 

[vairulez]

I agree with BrianC this should be integrated by default in MC especially in theaterview

[Moe]

I received a pm asking me for the final expression for how I achieved what I am doing, so instead of replying privately, I figured it was best if I just shared it with everyone. 

It may all look a bit complicated but I really don't think it's that bad, you just kind of have to wrap your head around it.  It also helps if you have a decent grasp of expressions.

I ended up making a few new custom fields to make things easier for me.  I figured it was easier to break the tooltip into little chunks and then piece it all together.  I've made a change or two since the last screenshot, so here is how it currently looks and the directions provided should get you this as a result.



I should also preface this post with the fact that I am metadata junkie and I am very meticulous when it comes to tagging my media.  I use the built in "Get Movie & TV Info" function, the amazing MCUtils (created by the much missed MrC) and zybex's MCRatings to gather data.

I should also add that I heavily used lepa's code as a starting point and a lot of what I have done would not be possible without his work (thank you!).  I also highly suggest creating separate fields for different media type tooltips and then use this expression in the actual tooltip field.

Code: [Select]

FirstNotEmpty([Tooltip - Movie], [Tooltip - TV Show], [Tooltip - Audio])
Here is the final code, placed in the [Tooltip - Movie] field referenced above, that I used to create my tooltip.

Code: [Select]

If(IsEqual([Media Sub Type],Movie,1),<font size="200"><b>[Name]<//b><//font>
If(!IsEmpty([Tag Line]),<font size="150"><i>[Tag Line]<//i><//font>,)

 If(!IsEmpty([Oscar Winner]),[Oscar Winner],)   <font size="150">If(!IsEmpty([TMdbRating]),<font face="ToolTip01" size="150"><font color="#01CB73">;<//font><//font>  [TMdbRating] ,) If(!IsEmpty([IMDb Rating]),<font face="ToolTip01" size="150"><font color="##E8B708">7<//font><//font>  [IMDb Rating] ,)  If(!IsEmpty([Rotten Tomatoes]),<font face="ToolTip01" size="150"><font color="#ED1C08">8<//font><//font>  [Rotten Tomatoes]% [RT],)<//font>   

 If(!IsEmpty([MPAA]),[MPAA],)  [Audio_Stream]   [Speakers]   [Resolution]   [Aspect_Ratio] 

  <font size="150" color="#80C0C0"><b>[Duration] - [Genre] - [Year]<//b><//font>,)

<font size="150"><b><i><u>Synopsis                                                                                                 <//b><//i><//u><//font>
If(!IsEmpty([Synopsis]),<font size="115">[Synopsis]<//font>,)

<font size="150"><b><i><u>Credits                                                                                                    <//b><//i><//u><//font>
<font size="115">If(!IsEmpty([Director]),<b>Director:<//b> [Director]
,)If(!IsEmpty([Screenwriter]),<b>Screenwriter:<//b> [Screenwriter]
,)If(!IsEmpty([Producer]),<b>Producer:<//b> [Producer]

,)If(!IsEmpty([TMDB Actors]),<b>Cast:<//b> [TMDB Actors Short],)<//font>
If(!IsEmpty([Bonus_Section]),

<font size="150"><b><i><u>Bonus//Other                                                                                          <//b><//i><//u><//font>
<font size="115">If(!IsEmpty([Commentary]),<b>Commentary:<//b> [Commentary],)
If(!IsEmpty([Collections]),<b>Collections:<//b> [Collections],)
If(!IsEmpty([Movie Series]),<b>Movie Series:<//b> [Movie Series],)<//font>,)

If(!IsEmpty([Rifftrax]),
<font size="150"><b><i><u>Rifftrax                                                                                              <//b><//i><//u><//font>
<font size="115"><b>Rifftrax:<//b> [Rifftrax],)<//font>
,)

Lets start with the title of the movie and the tagline, this comes from this bit of code

Code: [Select]

<font size="200"><b>[Name]<//b><//font>
If(!IsEmpty([Tag Line]),<font size="150"><i>[Tag Line]<//i><//font>,)


I think this should be pretty self explanatory.  If it's not, ask and I will explain.  FYI, I am getting the tagline via the TMDB scriptlet in MCUtils.


-------------------------------------------------------------------------------------------------------------------------------------------------------------------------



The next part is all of the awards and ratings for the movie, it's this line of code.

Code: [Select]

If(!IsEmpty([Oscar Winner]),[Oscar Winner],)   <font size="150">If(!IsEmpty([Critic Rating]),<font face="ToolTip01" size="150"><font color="#01CB73">;<//font><//font>  [TMdbRating] ,) If(!IsEmpty([IMDb Rating]),<font face="ToolTip01" size="150"><font color="##E8B708">7<//font><//font>  [IMDb Rating] ,)  If(!IsEmpty([Rotten Tomatoes]),<font face="ToolTip01" size="150"><font color="#ED1C08">8<//font><//font>  [Rotten Tomatoes]% [RT],)<//font>
This part contains my first my custom field [Oscar winner], it looks like this

Code: [Select]

if(isequal([Awards], Oscar, 8), if(isequal([Awards], Won, 8), <font face="ToolTip01" size="150" color="#b59031">4<//font> <font face="ToolTip01" size="350" color="#FFFF00">@<//font>, <font face="ToolTip01" size="150" color="#b59031">4<//font> <font face="ToolTip01" size="350" color="#a6a6a6">@<//font>),)

I'll try and explain this as briefly as I can.  zybex's MCRatings tool returns results like this for movies that have won or been nominated for an Academy Award

Nominated for 1 Oscar. Another 7 wins & 10 nominations.
Won 3 Oscars. Another 235 wins & 326 nominations.

Basically, if the movie won or was nominated for an Oscar, the word Oscar will appear in the [Awards] field. So the first thing I do is look for the word Oscar

Code: [Select]

if(isequal([Awards], Oscar, 8),
I then look to see if the field [Awards]contains the word "Won", if it does I then tell it to return

Code: [Select]

<font face="ToolTip01" size="150" color="#b59031">4<//font> <font face="ToolTip01" size="350" color="#FFFF00">@<//font>
Which is just saying, use my custom font, called ToolTip01 and return the number 4 (which corresponds to the gold word Oscars symbol in my custom font) at a size of 150 and then return, at a size of 350, the @ symbol (which corresponds to the Oscar statue symbol in my custom font) with a color value of #FFFF00, which makes the statue gold.

If the Awards field does not contain the word "Won" then it returns this code

Code: [Select]

<font face="ToolTip01" size="150" color="#b59031">4<//font> <font face="ToolTip01" size="350" color="#a6a6a6">@<//font>)
Which is pretty much identical to the above, but the color has changed from #FFFF00 to #a6a6a6a to make the statue gray.  So, a gold statue means that the movie won an Oscar (since the word "Won" appears in the [Awards] field and a gray statue means it was only nominated.

If neither the word Oscar or Won appears in the [Awards] field then I have the expression return nothing. 

I sure hope this makes sense, it's a lot harder for me to explain than it is for me to do 


-------------------------------------------------------------------------------------------------------------------------------------------------------------------------


The next part is

Code: [Select]

<font size="150">If(!IsEmpty([TMdbRating]),<font face="ToolTip01" size="150"><font color="#01CB73">;<//font><//font>  [TMdbRating] ,) If(!IsEmpty([IMDb Rating]),<font face="ToolTip01" size="150"><font color="##E8B708">7<//font><//font>  [IMDb Rating] ,)
Which should be pretty self explanatory, the only thing that could be confusing is why I have it returning a ";" and "7".  These correspond to the TMDB and IMDB icons in my custom font.

The last bit of code in the Ratings/awards section pertains to Rotten Tomatoes, it looks like this

Code: [Select]

If(!IsEmpty([Rotten Tomatoes]),<font face="ToolTip01" size="150"><font color="#ED1C08">8<//font><//font>  [Rotten Tomatoes]% [RT],)<//font>
This is also referencing another custom field that I created called [RT], it looks like this

Code: [Select]

if(isequal([Rotten Tomatoes], , 0), , if(isequal([Rotten Tomatoes], 60, 6), <font face="ToolTip01" size="150"><font color="#F13008">:<//font><//font>,<font face="ToolTip01" size="150"><font color="#0FC152">9<//font><//font>))
Basically, how Rotten Tomatoes works, is if a movie has a rating of 60% or above it's considered "Fresh" if it's 59% or lower, it's considered rotten.  This bit of code displays either the tomato icon, (for fresh movies), which corresponds to the : in my custom font, or the rotten icon (for rotten movies) which corresponds to the 9 in my font.  I am getting the Rotten Tomatoe's rating from MCRatings.


-------------------------------------------------------------------------------------------------------------------------------------------------------------------------


Next up we have the MPAA, sound format, channels, resolution and aspect ratio.  This is all done with this bit of code

Code: [Select]

If(!IsEmpty([MPAA]),[MPAA],)  [Audio_Stream]   [Speakers]   [Resolution]   [Aspect_Ratio]
all of these are custom fields that I created.  I am not going to explain any of them, by now I am hoping you have a grasp of how all this works.  If I am just confusing the hell out of you, I apologize and feel free to berate me and ask me questions.  Anyway, here are the expressions used for each of these fields.

MPAA

Code: [Select]

<font face="ToolTip01" size="300">If(IsEqual([MPAA Rating],G),G,If(IsEqual([MPAA Rating],PG),H,If(IsEqual([MPAA Rating],PG-13),I,If(IsEqual([MPAA Rating],R),J,If(IsEqual([MPAA Rating],Unrated),L,If(IsEqual([MPAA Rating],NC-17),K,))))))<//font>
Audio_Stream

Code: [Select]

<font face="ToolTip01" size="300">if(isequal([Compression],DTS,8),#,if(isequal([Compression],AC3,8),z,if(isequal([Compression],PCM,8),/),if(isequal([Compression],mp3,8),+,if(isequal([Compression],flac,8),/(,if(isequal([Compression],aac,8),0,if(isequal([Compression],MPEG,8),à,if(isequal([Compression],Vorbis,8),/,,))))))))<//font>
[Speakers]

Code: [Select]

<font face="ToolTip01" size="300">if(isequal([Channels],1,2),=,if(isequal([Channels],2,2),>,if(isequal([Channels],3,2),],if(isequal([Channels],4,2),?,if(isequal([Channels],5,2),^,if(isequal([Channels],6,2),‐,if(isequal([Channels],7,2),_,‑)))))))<//font>
 [Resolution] (this one I use a bit of fuzzy logic on, it could probably be improved)

Code: [Select]

<font face="ToolTip01" size="300">If(IsEqual([Width],1920,5),¥,If(IsEqual([Width],1360,5),¤,If(IsEqual([Width],888,5),£,¡)))<//font>
[Aspect_Ratio] (A bit more fuzzy logic here  )

Code: [Select]

<font face="ToolTip01" size="300">ifelse(isrange([AR2,0],1.00-1.50),M,isrange([AR2,0],1.51-1.69),N,isrange([AR2,0],1.70-1.95),P,1,Q)<//font>

-------------------------------------------------------------------------------------------------------------------------------------------------------------------------


The rest of the code

Code: [Select]

  <font size="150" color="#80C0C0"><b>[Duration] - [Genre] - [Year]<//b><//font>,)

<font size="150"><b><i><u>Synopsis                                                                                                 <//b><//i><//u><//font>
If(!IsEmpty([Synopsis]),<font size="115">[Synopsis]<//font>,)

<font size="150"><b><i><u>Credits                                                                                                    <//b><//i><//u><//font>
<font size="115">If(!IsEmpty([Director]),<b>Director:<//b> [Director]
,)If(!IsEmpty([Screenwriter]),<b>Screenwriter:<//b> [Screenwriter]
,)If(!IsEmpty([Producer]),<b>Producer:<//b> [Producer]

,)If(!IsEmpty([TMDB Actors]),<b>Cast:<//b> [TMDB Actors Short],)<//font>
If(!IsEmpty([Bonus_Section]),

<font size="150"><b><i><u>Bonus//Other                                                                                          <//b><//i><//u><//font>
<font size="115">If(!IsEmpty([Commentary]),<b>Commentary:<//b> [Commentary],)
If(!IsEmpty([Collections]),<b>Collections:<//b> [Collections],)
If(!IsEmpty([Movie Series]),<b>Movie Series:<//b> [Movie Series],)<//font>,)

If(!IsEmpty([Rifftrax]),
<font size="150"><b><i><u>Rifftrax                                                                                              <//b><//i><//u><//font>
<font size="115"><b>Rifftrax:<//b> [Rifftrax],)<//font>
Should be pretty self explanatory, as it's pretty straight forward.

Ugh, reading this post after writing it I feel like I have just muddied the waters.  Hopefully it makes sense, I have end of the week brain so please forgive me.  I am happy to clarify any of the above if needed.

I can see people getting confused with how the number 7 returns the imbd icon.  I highly recommend going to https://moesrealm.com/MC/ and typing in some letters/numbers and seeing what is happening.  Or better yet, double click the very first icon, which is the G rating, so that it turns blue and then copy it.  Once it's copied paste it into notepad or something and see what happens (spoiler alert, it will return the letter "A") as I think that will help understand what's going on.

Okay, I've been working on this post for about 2 hours, time to call it quits.  I hope it helped more than it hurt! 

[lepa]

I think that you need to encapsulate whole [Tooltip - Movie] with [Media Sub Type]=Movie in order to get this tooltip only for the movies. Otherwise it just select first one i.e. Tooltip Movie for the all files. You probably have it yourself but just note for others.

So [Tooltip - Movie] expression would start with

Code: [Select]

If(IsEqual([Media Sub Type],Movie,1),
and end with

Code: [Select]

,)
Whole thing
If(IsEqual([Media Sub Type],Movie,1),YOUR EXPRESSION HERE,)


EDIT:

If neither the word Oscar or Won appears in the [Awards] field then I have the expression return the field [Altitude].  There may be a better way to do this, but I know that the Altitude field will be empty so it will return nothing.  I am happy to get an education here for a better way to do this.

You can just leave it empty:

Code: [Select]

If(IsEqual([Awards], Oscar, 8), If(IsEqual([Awards], Won, 8), <font face="ToolTip01" size="150" color="#b59031">4<//font> <font face="ToolTip01" size="350" color="#FFFF00">@<//font>, <font face="ToolTip01" size="150" color="#b59031">4<//font> <font face="ToolTip01" size="350" color="#a6a6a6">@<//font>),)

[Moe]

Oops, you were totally right.  I have edited the post.

I had another idea last night that I am working on.  I should have something to show shortly

You can just leave it empty:

I could have sworn I tried this, repeatedly, but I couldn't get it to work.  I just tried again and it works.  Thanks   Edited the above as well.

[lepa]

I could have sworn I tried this, repeatedly, but I couldn't get it to work.  I just tried again and it works.  Thanks   Edited the above as well.

Maybe you had deleted also the comma.  Happened to me...

[MGD_King]

Whole thing
If(IsEqual([Media Sub Type],Movie,1),YOUR EXPRESSION HERE,)

Lepa, can you provide a little more clarity for this? I have two custom fields, [Tooltip - Audio] and [Tooltip - Movie], but what do I put in your expression to make it work on each custom field? And that expression you provided goes into the [Tooltip] custom field, correct?

[Moe]

Lepa, can you provide a little more clarity for this? I have two custom fields, [Tooltip - Audio] and [Tooltip - Movie], but what do I put in your expression to make it work on each custom field? And that expression you provided goes into the [Tooltip] custom field, correct?

You're going to want to wrap your individual Tooltip expressions in this bit of code.  So for example, the beginning of your Movie Toop tip field will have

Code: [Select]

If(IsEqual([Media Sub Type],Movie,1),YOUR EXPRESSION HERE,)
The beginning of your Tooltip Audio field will have

Code: [Select]

If(IsEqual([Media Sub Type],Audio,1),YOUR EXPRESSION HERE,)
The YOUR EXPRESSION HERE part is where you're going to want to put the view specific details. 

[lepa]

Lepa, can you provide a little more clarity for this? I have two custom fields, [Tooltip - Audio] and [Tooltip - Movie], but what do I put in your expression to make it work on each custom field? And that expression you provided goes into the [Tooltip] custom field, correct?

So if you want to have custom tooltip for movie, tv show and audio then you would make calculated field [Tooltip]

Code: [Select]

FirstNotEmpty([Tooltip - Movie], [Tooltip - TV Show], [Tooltip - Audio])
Then you would make 3 more calculated fields [Tooltip - Movie], [Tooltip - TV Show], [Tooltip - Audio]

[Tootip - Movie] calculated Expression would be for example like in second picture.. or starts like that

So the [Tooltip] calculated field works like this:
- In this [Tooltip - Movie] You are only inserting metadata for [Tooltip] field if file in question is movie. if it is not then nothing is written from this calculated field.

- Then it moves to [Tooltip - TV Show] and same thing will happen. in the start of [Tooltip - TV Show] calculated field expression we'll put if decision that only write these if subtype is tv show.... and so on. If nothing fits then default tooltip should be visible

More discussion about custom tooltips can be found in here

EDIT: Okay I answered to wrong question but luckily Moe already explained the right thing....

[MGD_King]

EDIT: Okay I answered to wrong question but luckily Moe already explained the right thing....

Figured it out!!! Thanks!!! This works great!! Now I can customize each custom field!

Thank you, and Moe both for doing all the heavy lifting on this! This is a really awesome feature of MC that I wasn't aware of, and quite honestly, was a little intimidated by it. 

[Moe]

Okay, what do you all think about this?  I felt like Genre could be spiced up a bit, so this is what I've come up with so far.  I've only really done Horror



Here is one of the icons with all the other data



I have a bunch of other icons that I can use for other genres as well.  You can see what I've got so far here https://moesrealm.com/MC/genre-icons/ just a word of warning.  There are some comically simply adult ones there, so if you are incredibly easy offended, then don't click that link.

Also, I stick to a very select set of Genres, they are:

Action/Adventure
Adult
Anime
Comedy
Documentary
Drama
Fantasy
Horror
Musical
Science Fiction
Short
Thriller
Western

So, at least in the beginning I am going to focus on those.  If enough people are interested and there is demand for other Genres, I will try and accommodate.

I could also use some help.  I can't think of anything good to represent Drama.  I have the drama mask Icon but that's about it, suggestions very welcome.  Could also use suggestions for Documentary and for Shorts.

[Moe]

Since I made all the different horror icons, I didn't want to just choose one.  So, I figured out a way to return a random one.

Here is how I did it.  I made a new field called [Random] with the following value.

Code: [Select]

right([Duration], 1)
All this does is return the last number of the movies duration time.  So if a movie is 1:25:44 it returns the number 4.  I figured this was a quick and easy way to generate a random number.

I then made another new field called [Horror Icon] with the following value

Code: [Select]

<font face="Horror" size="150">if(isequal([Genre],Horror,1),
if(isequal([Random],1,1),A,
if(isequal([Random],2,1),C,
if(isequal([Random],3,1),D,
if(isequal([Random],4,1),H,
if(isequal([Random],5,1),I,
if(isequal([Random],6,1),J,
if(isequal([Random],7,1),K,
if(isequal([Random],8,1),L,
if(isequal([Random],9,1),M,N))))))))),)<//font>
Here is the end result in theater view

[lepa]

I have a bunch of other icons that I can use for other genres as well.  You can see what I've got so far here https://moesrealm.com/MC/genre-icons/ just a word of warning.  There are some comically simply adult ones there, so if you are incredibly easy offended, then don't click that link.

I only guessed those genres from the icons 
Seriously though it might be hard to make genre icons easily understandable for casual viewer without words. That said I'm curious what you can make with genre icons.  ....oh cool with the random icon... and it seems you also have genre as a word in there..

Tried to do something with TheaterView. Not yet sure how to integrate technical icons as so far I have failed miserably to get them look as a part of whole structure. They always seem to look like outsiders. Anyway here is a picture to which I'll settle it for the night

[Moe]

I think what you have so far looks awesome, nice work.

[lepa]

I think what you have so far looks awesome, nice work.

Thanks I kind of like too. Basically it's your rating row 
Second row is borrowed from imbd. Realized from screenshot that I now have country two times so replaced the other one with writer and added keyword list. Tomorrow I'll try to figure out those technical data icons but now when there already is some eye candy represented by the ratings row it already looks quite nice

[thorsten]

Hi everyone,

thanks for your impressive work!

I, as a newbee to this area of MC, managed to get the tag- fields filled.

However, 2 things don't work:
1 - the custom logos aren't shown. Where do I have to copy the MCTooltip fond file? I copied it to programs\MC25\ but it seems it must be another folder...


2- despite the [Tooltips - Movie] field is filled correctly, it doesn't appear to the hovering mouse.

I just restarted the PC, but that didn't help.

Any suggestions?

[lepa]

1 - the custom logos aren't shown. Where do I have to copy the MCTooltip fond file? I copied it to programs\MC25\ but it seems it must be another folder...

You need to install font in Windows. Right click on explorer and then select install