Print

Please login or register.
1 Hour 1 Day 1 Week 1 Month Forever
Login with username, password and session length

[jmone]

Last Updated: 09 Aug 2015

Background:  MC Lets you launch external programs by File Type (Tools --> Options -->File Types). Though control of these programs is pretty limited.  Following on from my previous threads of:
3D BD : Integrating a 3rd Party Player with MC ** now old **
Another Way To Watch Netflix With a 10 Foot Interface & RC (Win8/10 only) ** still current **

I've decided to make a more generalised "Advanced External Program Launcher" to complement MC's existing capabilities and included three profiles for:

1) CyberLink PowerDVD : MC Users who want 3D or Full Menu support for their Bluray Library and Disks.

2) Stereoscopic Player : MC Users who want MVC-3D MKV Support (aka 3D BD Rips)

3) Arcosft TotalMediaTheatre : MC Users who want 3D or Full Menu support for their Bluray Library and Disks and still have this older program

What it does now:
    When commencing play for a specific file type (say BDMV3D or MK3D) in MC it:
     - Optionally Turns on NVIDIA's 3D Profiles (if needed)
     - Plays your title in PowerDVD / Stereoscopic Player / TotalMediaTheatre
    When you press the "STOP" button on your Remote Control
     - Closes PowerDVD / Stereoscopic Player / TotalMediaTheatre
     - Turns off NVIDIA's 3D Profiles (if needed) and resets the Screen Setting back to what you had in MC
     - Returns to MC

What it could do:  The script is setup so you can add or modify profiles to suit a range of 3rd Party apps.  It does some conversion of selected MCE IR Remote Control commands into Keyboard keystrokes (as with the separate Netflix script) for those apps that don't support some RC commands, or where there is a conflict with MC itself.  Feel free to modify, add, and share any script changes as I've only added the three profiles and tested with my setup.

What you need to do:  Here is how to configure the lot to work together:
1) Install AutoHotKey if you want to edit the script (free scripting app that does all the work)
2) Use the attached script as a template, or edit to suit your needs.  I've attached both the script (as shown below) and a compiled version if you don't need to make any changes to the one I've generated (and then you don't need to install AutoHotKey)

Code: [Select]

; JRiver Media Center Advanced External Program Launcher Verrsion: 150809
; Author: jmone
; Thread on Interact: http://yabb.jriver.com/interact/index.php?topic=98984.0

; --------------------------------------------------------------------------------------------------------
; AutoHotKey Environment Settings - No need to change
; --------------------------------------------------------------------------------------------------------
#NoEnv
;#NoTrayIcon
#Persistent
#SingleInstance, Force
SendMode Input
SetWorkingDir %A_ScriptDir%
SetTitleMatchMode, 2
SetTitleMatchMode, Slow

; --------------------------------------------------------------------------------------------------------
; Record existing Display Settings - No need to change
; --------------------------------------------------------------------------------------------------------
VarSetCapacity(device_mode,126)
success := DllCall("EnumDisplaySettings","uint",0,"uint",-1,"uint",&device_mode)
sW:=NumGet(&device_mode,108,"uint4")  ;width
sH:=NumGet(&device_mode,112,"uint4")  ;height
cD:=NumGet(&device_mode,104,"uint4")  ;bit depth
rR:=NumGet(&device_mode,120,"uint4")  ;frequency

; --------------------------------------------------------------------------------------------------------
; Read and Check Variables sent from MC - No need to change
; --------------------------------------------------------------------------------------------------------
Loop, %0%  ; For each parameter:
{
    Par%A_Index% := %A_Index%
}
StringSplit, Var,Par1, `,

If !Var1 ; check there is a filename specified
{
  msgbox There is Nothing to play - Process will Close
  ExitApp
}
If !Var2 ; check there is an external player specified
{
  msgbox There was no External Player specified - Process will Close
  ExitApp
}

StringReplace,Var1,Var1,BDMV\index.bluray;1,  ;shortens MC's Bluray "Filename" to just the Path

; the following checks to see if it is file or on a Disk Drive and then finds the drive letter to use
If Var1 not contains \\,:
{
  StringReplace, Var1, Var1, %A_SPACE%, _, All
  StringGetPos, pos, Var1, \
  StringLeft, Var1, Var1, pos
  DriveGet, l_Temp, List
  Loop, Parse, l_Temp
  {
    DriveGet, Label, Label, %A_LoopField%:
    If Label contains %Var1%
    {
      Var1 = %A_LoopField%:\
      Break
    }
  }
}

; ********************************************************************************************************
; User Settings - Edit the values to match your player below
; ********************************************************************************************************
-------------- Media Center Configuration ----------------------------------------------------------------
If ProcessExist("Media Center 20.exe")
{
  MC_Path:="C:\Program Files (x86)\J River\Media Center 20\Media Center 20.exe" ; Enter Full path to MC
  MC_Name:="MC20.exe" ; Enter Short MC Name
}
If ProcessExist("Media Center 21.exe")
{
  MC_Path:="C:\Program Files (x86)\J River\Media Center 21\Media Center 21.exe" ; Enter Full path to MC
  MC_Name:="MC21.exe" ; Enter Short MC Name
}

-------------- NVIDIA 3D Vision --------------------------------------------------------------------------
P_N3D:="C:\Program Files (x86)\NVIDIA Corporation\3D Vision\nvstlink.exe" ; Enter Full path to nvstlink
-------------- Cyberlink PowerDVD Configuration ----------------------------------------------------------
If Var2=PDVD ; Enter Abbreviation of the Program to run that will be used in the Second Variable from MC
{
  P_DIR:="C:\Program Files (x86)\Cyberlink\PowerDVD15\PDVDLP.exe" ; Enter the Full path to the Program
  P_WinName:="PowerDVD" ; Enter the Title of the Window when running
  P_Switch:="/LaunchProgram PowerDVDCinema" ; Enter any Additionial Switches to include
  P_Prev = P ; Remaps the PgUp Button on a RC to a Keyboard Command
  P_Next = N ; Remaps the PgDn Button on a RC to a Keyboard Command
}
-------------- Stereoscopic Player Configuration ---------------------------------------------------------
If Var2=SP ; Enter Abbreviation of the Program to run that will be used in the Second Variable from MC
{
  P_DIR:="C:\Program Files (x86)\Stereoscopic Player\StereoPlayer.exe" ; Enter the Full path to the Program
  P_WinName:="Stereoscopic Player" ; Enter the Title of the Window when running
  P_Switch:="-fss" ; Enter any Additionial Switches to include
  P_Prev = ^{PgUp} ; Remaps the PgUp Button on a RC to a Keyboard Command
  P_Next = ^{PgDn} ; Remaps the PgDn Button on a RC to a Keyboard Command
}
-------------- Arcsoft TMT Configuration -----------------------------------------------------------------
If Var2=TMT ; Enter Abbreviation of the Program to run that will be used in the Second Variable from MC
{
  P_DIR:="C:\Program Files (x86)\ArcSoft\TotalMedia Theatre 6\uMCEPlayer6.exe" ; Enter the Full path to the Program
  P_WinName:="TotalMedia" ; Enter the Title of the Window when running
  P_Switch:="" ; Enter any Additionial Switches to include
  P_Prev = {PgUp} ; Remaps the PgUp Button on a RC to a Keyboard Command
  P_Next = {PgDn} ; Remaps the PgDn Button on a RC to a Keyboard Command
}

; ********************************************************************************************************
; User Settings - Edit the values to match your player above
; ********************************************************************************************************
; --------------------------------------------------------------------------------------------------------
; Launch Player - No need to change
; --------------------------------------------------------------------------------------------------------
Progress, b w200, Launching %P_WinName%, Please Wait
If Var3=N3D
{
  run %P_N3D% /enable
  Progress, 50
  Sleep, 4000
}
Run %P_DIR% "%Var1%" %P_Switch%
Progress, 75
sleep, 1000
Progress, Off
WinMaximize, P_WinName

; --------------------------------------------------------------------------------------------------------
; Media Key Handling
; --------------------------------------------------------------------------------------------------------
Media_Prev::
  Send %P_Prev%
return

Media_Next::
  Send %P_Next%
Return

Media_Stop::  ; This is the STOP button (Media_Stop) - you can change to suit your requirements
  WinClose, %P_WinName%
  If Var3=N3D
    run %P_N3D% /disable
  ChangeDisplaySettings( cD, sW, sH, rR )
  ExitApp

; --------------------------------------------------------------------------------------------------------
; The script that makes various System Calls - Don't Change
; --------------------------------------------------------------------------------------------------------
ChangeDisplaySettings( cD, sW, sH, rR )
{
  VarSetCapacity(dM,156,0), NumPut(156,2,&dM,36)
  DllCall( "EnumDisplaySettings", UInt,0, UInt,-1, UInt,&dM ), NumPut(0x5c0000,dM,40)
  NumPut(cD,dM,104),  NumPut(sW,dM,108),  NumPut(sH,dM,112),  NumPut(rR,dM,120)
  Return DllCall( "ChangeDisplaySettings", UInt,&dM, UInt,0 )
}  

ProcessExist(Name)
{
Process,Exist,%Name%
return Errorlevel
}

[jmone]

Configuring the MC_AEPL script:  The script is already configured for PDVD and Steroscopic Player, though you may need to make changes if any of the installation directories are not the default.  I've tried to keep all of these in the section marked "User Settings" so they should be easy to modify if needed.  There are then sub-sections for:
- MC's details (Installation Path and running Program Name)
- NVIDIA 3D Vision Toggler (Installation Path)
- PowerDVD / Steroscopic Player / TotalMediaTheatre (Installation Path, it's running Windows Title, and any additional parameters/switches it needs).

Configuring MC: Under Tools --> Options --> File Types you can specify for each file type a "Playback Method".  Change this from "Automatic" to "External Program (custom)" and complete the details in the following examples (and as shown in the pics):
- Program: Path to where you are running MC_AELP.ahk (or .exe if you have compiled it)
- Arguments:  These are in the form of "[The Item To Play],What External Player to Use,IF You Want to Enable NVIDIA 3D"
Note: You must wrap all the Arguments in Quotes.

Valid Arguments are:
[The Item To Play] : use [Filename]
[What External Player to Use] : use either PDVD or SP or TMT (for PowerDVD, Steroscopic player, and TotalMediaTheatre respectively)
[IF You Want to Enable NVIDIA 3D] : N3D if you want to Enable the setting, else leave it blank



Notes:  Couple of thing I've found:
- Make sure you system is all working fine first (including 3D viewing).  This script just calls the various bits and will not "fix" something that is broken.
- I don't like how the NVIDIA does it 3D profile as when you enable it, you lose "std" 2d 23.976 and 24hz profiles.  The toggle was added to get around this by turning it on and off.  I have noticed that after a few toggles it all seems to be working but you are not seeing 3D.  If that is the case a reboot fixes it.

[jmone]

CyberLink PowerDVD Profile Information

Firstly, thank you to Cyberlink who gave me a Licence to PowerDVD do this testing and writeup (FYI - I'm a "Cyberlink MVP" on their Video Editing application PowerDirector)    It makes it much easer than using the Trial Software!

Additional Features over MC: PowerDVD is a full featured BD player supporting both MVC 3D, Menu Navigation and BD Live etc.

Sample Configuration:  The following is the configuration to use PDVD as a 3D Bluray player (see pic) for both 3D BD's ripped to a file structure in MC's library and Physical Disks / Mounted ISO
- 3d Blu-ray (bdmv3d) : Argument="[Filename],PDVD,N3D"  (I want to run PowerDVD for 3D Bluray and switch on NVIDIAs 3D profile)
- 3d Blu-ray (bdmv3d) : Argument="[Filename],PDVD"         (I want to run PowerDVD for 3D Bluray)

You could also use PowerDVD for all BD Playback if you prefer full Menu support by
- Blu-ray (bdmv,mpls) : Argument="[Filename],PDVD"          (I want to run PowerDVD for std Bluray)

Notes:
- I'm in conversation with Cyberlink on PDVD's support for playback of MVC MKV3D files in 3D.  At this stage I can only get them to play in 2D AVC
- Product Page CyberLink PowerDVD
- Support Page CyberLink Community Forum

[jmone]

Stereoscopic Player Profile Information

This is a File Based player that support a wide range of 3D formats and Outputs.  Of interest to most on this forum it support MVC (aka 3D BD rips in MKV).  

Additional Features over MC: Supports MVC encoded MKV (aka MKV 3D / 3D BD to MKV rips).

Sample Configuration:  The following is the configuration to use Stereoscopic Player as a MKV 3D MVC player (see pic)
- Matroska Video 3d (mk3d) : Argument="[Filename],SP,N3D"  (I want to run Steroscopic Player for 3D MKV and switch on NVIDIAs 3D profile)
- Matroska Video 3d (mk3d) : Argument="[Filename],SP"         (I want to run Steroscopic Player for 3D MKV)

You could also use Stereoscopic Player for SSIF (from a BD Folder Structure rip).  You would need to .......
- .....I've got this working but it is a bit of a PITA - asked if JR can make some changes first then I'll update ....TBD .....

Notes:
- Stereoscopic Player requires a working NVIDIA 3DTV Play and it has to be Activated (paid for).
- As it is a file based player it has no direct support form playing a 3D BD structure/disk though it can play the SSIF files or MKV.
- Product Page Stereoscopic Player Overview
- Support Page - no dedicated forum by the MFR
- Stereoscopic Player does not support the use of Chapters for navigation though I remapped the MCE Chapter buttons to Jump Forward / Jump Back

[jmone]

Arcsoft TotalMediaPlayer Profile Information

Arcsoft have deprecated this player and it is really no longer recommended as without updates bugs can not be fixed and issues of compatibility are already appearing.  While the initial version of TMT6 (6.0.1.119) does run on my system, the final version (6.7.1.199) causes a BSOD in Windows 10 on all my NVIDIA based PCs and  I've seen other posts on AMD systems saying it will not run.  The initial version of TMT6 (6.0.1.119) does run on my system.

Additional Features over MC: TMT is a full featured BD player supporting both MVC 3D, Menu Navigation and BD Live etc.

Sample Configuration:  The following is the configuration to use TMT as a 3D Bluray player for both 3D BD's ripped to a file structure in MC's library and Physical Disks / Mounted ISO
- 3d Blu-ray (bdmv3d) : Argument="[Filename],TMT,N3D"  (I want to run TMT for 3D Bluray and switch on NVIDIAs 3D profile)
- 3d Blu-ray (bdmv3d) : Argument="[Filename],TMT"         (I want to run TMT for 3D Bluray)

You could also use TMT for all BD Playback if you prefer full Menu support by
- Blu-ray (bdmv,mpls) : Argument="[Filename],TMT"          (I want to run TMT for std Bluray)

Notes:
- Pending your Version some MKV playback may not work, a Hotfix is here
- Product Page : No Longer Sold or Supported
- Support Page ArcSoft TotalMedia Forum

[jmone]

Found a bug - First post updated with latest script and also changed how to put in Arguments in MC.

Any feedback on how it works is welcome

[bhampster]

Thank you,

This is great and you are miles ahead of me but I do believe that Nvidia 3D play is not required. Stereoscopic player can use DirectX quad buffered playback and Nvidia doesn't have to have any idea what's going on.

Then again,... I may not know what I'm talking about here. I've only played back a little 3D so far till I get it all figured out.

I was fascinated by a post showing how to merge the unregistered Stereoscopic player with Nvidia 3D Vision player and that DID work for me but the 3DVision player seemed only to want to display TAB 3D with no option to do frame packing. There may be a way to resolve that but I can't spend too much time trying to evade purchase of Stereoscopic player outright.

-Brian

[jmone]

Thanks Brian.  I could not get my TV to kick into 3D in any other mode apart from "NVIDIA 3D Vision" in SP when playing MVC MKV content ...  and even then it would only work once I and activated NVIDIA 3DTV Play (note: you don't need to run the player but just active it).  Once I did that it work flawlessly.  I should say I'm also only running the trial of both SP and 3DTV Play Activation.... so who knows. 

[gvanbrunt]

Thanks for this. I'll get to testing when I have some time.

FYI: I too need to activate 3D vision support in my NVIDIA for any kind of 3D to happen with my TV in any apps I've tried.

[jmone]

We may be talking on two different things:
1) You need to turn the 3D settings on (through the NVIDIA Control Panel or programatically) for any 3D prog to work at all, but
2) Stereoscopic Player (but not PDVD) seems to also require that the additional NVIDIA 3DTV SW is installed and that you pay for a licence key to Activate it

[TorqW]

Thank you JMOne. Fantastic. Exactly what I was looking for after a frustrating afternoon trying to get powerdvd to work with MC20.

A great solution. Works way better than TMT6 for me.

Now I just need to sort out the spdif sound issues and it'll be a perfect solution.

Thanks again.

[TorqW]

Actually....can powerdvd output audio to the MC wdm driver?
Might be a solution to get the audio processed correctly.

[jmone]

It should work but give it a go in PDVD first.  You may need to make the MC WDM driver the default first (as in PDVD I can see no way of picking a particular Audio Renderer) and then select the output Audio Driver in MC to the real output.  Once that works you then may need to comment out the command the closes MC in the script so it is still running and can process the Audio from PDVD.  I'll be able to test but not for a few days.

Thanks for the feedback
Nathan

[gvanbrunt]

We may be talking on two different things:
1) You need to turn the 3D settings on (through the NVIDIA Control Panel or programatically) for any 3D prog to work at all, but
2) Stereoscopic Player (but not PDVD) seems to also require that the additional NVIDIA 3DTV SW is installed and that you pay for a licence key to Activate it

Ah gotcha. I never used Stereoscopic Player yet. I was able to get PDVD to work without the NVIDIA add on. Don't know if that makes any difference.

[TorqW]

Nathan - look forward to hearing about your test results. It would be a shame to have to keep MC20 open as, as you say, it inhibits some of the remote control functions. I'm hoping that the wdm driver uses the settings from MC20 but doesn't ACTUALLY need to have MC20 open.....but I guess we'll see.

As I'm playing the audio to only stereo speakers, TMT6 at least could remix the source appropriately. PowerDvd doesn't seem to have that ability, so routing the 5.1 sound through the MC20 driver would be a good solution.

Thanks again for your excellent solution.

[Hendrik]

I'm hoping that the wdm driver uses the settings from MC20 but doesn't ACTUALLY need to have MC20 open.n.

The WDM driver only ever works when MC is running.

[JimH]

Nathan,
Thanks very much for doing this guide.

Jim

[jmone]

No probs Jim.  Nothing like brushing up on my "parsing" skills.... it has been a very long time.

I'll check out how to use the WDM driver that will necessitate keeping MC running but keeping MCE commands...

[TorqW]

Thanks again Nathan. I guess getting the MCE commands to function correctly is all we're looking to do here and then we have pretty much the ideal solution.

[jmone]

It should not be a big deal.  I only noticed a couple of MCE commands were being eaten ( <<| and |>>) and I think I can handle these in the script.  I should have something done in the next couple of days.
Thanks
Nathan

[jmone]

ugg - no problems in keeping MC running and pumping audio via the WDM driver.... but I've still got more to do to try to stop MC eating the RC commands without using a prog like Even Ghost or Girder (which you could use now and get it all going).  I've not spent as much time as I'd like and Win10 happened!

[TorqW]

Thanks again Nathan. Look forward to seeing how you deal with MC command eating!

[Ekpen]

It should not be a big deal.  I only noticed a couple of MCE commands were being eaten ( <<| and |>>) and I think I can handle these in the script.  I should have something done in the next couple of days.
Thanks
Nathan

Greetings:

Anyway to add TMT6?

I just found my license key , I will like to test with TMT6.

Thanks Nathan

George 

[CountryBumkin]

Greetings:

Anyway to add TMT6?

I just found my license key , I will like to test with TMT6.

Thanks Nathan

George 

See this earlier thread/work from jmone which is about using TMT https://yabb.jriver.com/interact/index.php?topic=81259.0

[Ekpen]

See this earlier thread/work from jmone which is about using TMT https://yabb.jriver.com/interact/index.php?topic=81259.0

Greetings:

What you pointed me to was an old method. The new script is compiled, but it does not include the TMT6 or so. If tmt6 is added, we will have three options or switches.
I am going to test all to see which one works better.
Of course, this is on Windows machine. When I get to use the Linux- Ubuntu, we have to find other ways of doing this.
I read something about Bino or vlc.
I do not think there is a working equivalent of auto hotkey in Linux.
Thanks anyway.
George

[jmone]

I've got some new code working with TMT but need need to to test some more I've not broken PDVD etc (plus I then need to then update the instructions).  I've not done much more on MC grabbing RC codes.

[Ekpen]

I've got some new code working with TMT but need need to to test some more I've not broken PDVD etc (plus I then need to then update the instructions).  I've not done much more on MC grabbing RC codes.

Thanks for taking your time to do this for all of us.

George

[jmone]

See how this works and let me know.... but it's not really tested, but it should:
- Adds support for TMT
- Recognises if you are calling it from MC20 or MC21 automatically and close / restart the correct version (note: I've still not worked out the key mapping so MC still closes at this stage)
- changed the arguments so it is consistent regardless of if it is a File or a BD Structure to be played and should now all be in the form of
"[Filename],PDVD,N3D" , "[Filename],TMT,N3D", "[Filename],SP,N3D" with the ",N3D" an optional flag

I've also been in discussion with Cyberlink on a few things like support for 3D-MKV but I need to check a few things to be sure.

Let me know what works / does not work and I'll push out a version and update the first set of posts.
Thanks
Nathan

Edit - Removed Old Version

[jmone]

Here is the latest version.  In addition to the above this one:
- Leaves MC Open so you can pump audio through the WDM driver if you want
- Remaps the MCE Media_Prev and Media_Next that MC eats if it is open for PDVD and TMT.  It also now does a Skip forward and Skip backward for SP which does not support chapters (so at least you get some ability to jump back and forward).

Again - any feedback please so I can update the first post.

Also with TMT..... I've been testing on Win10 and have found that while V6.0.1.119 runs, the final V6.7.1.199 causes and immediate BSOD.  I've seen another post to the same effect and as Arcsoft have deprecated this package, it will not be fixed.

Edit - Removed Old Version

[jmone]

Another update.

Added support for 3D BD Discs that will following the settings under Video --> 3d Blu-ray (bdmv3d).  Note the settings options under Other --> Blu-ray are irrelevant.  One thing I've found is that MC keeps a list in the library of all disks it has played, so if you played a 3D BD prior to the version of MC that added the BD 3D option it may still only be recognised as a 2D disk.  If this is the case you will need to remove the entry from the MC database first.

Let me know of any feedback as I've started to update the main pages of this guide.

[jmone]

Update of the First 5 Pages with new script and instructions

[TorqW]

Nathan.

Fantastic job. Thank you.

A couple of issues outstanding on my side:

- when I start, pdvd left/right/up/down doesn't work until I press the menu button on remote control, which then forces me to choose which menu I want. After that it's fine.

- when I quit back to jriver from pdvd, I have a screen asking "Would you like to play the current disc in your drive?", with a yes/no response option. Any way to get rid of this?

Excellent solution otherwise!

[jmone]

Thanks for the feedback;
- Direction Button: I'll check on remapping the direction buttons and let me know if any others don't work as well
- I've not seen the "Would you like to play the current disc in your drive?" so a few of Q:  I presume it is a MC Diag Box?  If so is it related to the Disk you just played (eg is it like it is trying to play it a second time).  Can you tell when the Diag Box appears (eg as PDVD starts can make it a window) or if it is related to a key press (like Enter?) etc.

Nathan

[jmone]

Found the issue.  The "Menu" button is instructing MC to go the the Menu of a Disk, and the "Info" button is taking MC to Playing Now behind PDVD..... now what to do about it!

[jmone]

Ok - try this one.  The "Menu" and "Info" button still does stuff in MC behind the scenes but I then Stop and Restart MC when pressing "STOP" in PDVD so you end up with a clean MC instance.  I think I've also fixed the nav buttons working upfront.  Let me know how it looks.

Edit - Removed Old Version

[TorqW]

OK - this is excellent. Nav Buttons now work immediately in PDVD, and I have no complaints about MC closing and reopening.

The only issue remaining is that the pause and play buttons don't seem to work.

Otherwise, great stuff Nathan! This is an awesome solution and means I can enjoy so much more of my blu-ray collection's bonus features.

[jmone]

Thanks for the Feedback.  Has the Play/Pause button ever worked for you in any version of the script post the initial script that used to close MC?  as they work for me.  I can remap these buttons to keyboard commands but in addition have asked if the JR team would consider a MCC to disable MC reacting to MCE commands.....as it would make this much more consistent.

Attached is an untested (as I can't get to my HTPC at present) script remapping the Media_Play_Pause to the Space bar (all three apps support {space} for play/pause toggling).  Does this work?

[TorqW]

Works a charm. Perfect thank you.

One last thing....but I'm almost embarrassed to ask - you've done so much already!
I've noticed (even before your latest version) that it doesn't always reopen MC after shutting PDVD, leaving windows desktop exposed.
If you can't think of a fix, then maybe better to keep MC open after all and deal with spurious MC messages.

Finally (although I imagine this is more likely a problem with PDVD and will need to be fixed by cyber link), I've seen PDVD quit after 30 secs or so of playing a film or special feature and go to its own menu. I then need to quit PDVD and restart it and then it's fine.

[jmone]

I've not seen any issues with MC not starting or PDVD going away.  But here is another test build:
- I'll try not to close/open MC at the end but instead will put MC TheaterView will be put in the Exit Diag Box on purpose and the remove it later
- Pressing "0" will check if the external player is running and if not run it again (in case it closes / crashes)

All this media key handling to avoid MC doing stuff is really a big kludge, so I hope my request for a command to disable MCs media key handing gets done or I'm guessing there will always be issues.  The purpose of keeping MC running is for those that want to use the WDM driver (but good luck in getting Lip Sync to work well!)

Thanks
Nathan

[TorqW]

Thanks again Nathan.
Will try this evening.

Can you try opening a film or special feature and let it run for a couple of minutes? I've seen this a number of times now that after 30secs or so, the screen suddenly goes black and then a PDVD screen of all the films in my library appears - yet it doesn't allow me to watch any of them! I then have to close PDVD with the STOP button and re-enter.

Just wondered if there's anything in your script waiting for 15 or 30 secs before attempting to do something that PDVD doesn't like. It's intermittent, but happens enough to be annoying. If not I think we can assume it's a PDVD prob that they'll hopefully correct in an update.

As regards lip sync - I set the buffer to 10ms and everything works a charm through WDM with minimal sync issues.

Thanks to your hard work I'm enjoying my blu-ray library (above all the bonus features) more than I have in years!

[jmone]

Playing Avatar as we speak using the script and WDM and I'm 15mins in without issues.  I've not seen any issues with PDVD stoping playback like what you describe unless I hit the "return" button on the RC.  The script does not do anything post running PDVD unless you hit one of the buttons I remap.  Do you also see the same issue if you run PDVD on it's own?  Not a network connectivity issue?  Does it coincide with any activity or button pressing?  Glad you have WDM working well.

I'm hoping that if JR do the command I need I'll be able to clean this script up a fair bit but it will not help your random PDVD stopping playback.

[TorqW]

Have re-installed PDVD to see if that makes a difference.

Will test your latest version tonight.

Fingers crossed the JR developers implement your request!

[TorqW]

Great. So the reinstall of PDVD seems to have removed problems of quitting mid movie. Hurrah.

Otherwise, the latest version works really well. Only had one issue where it couldn't work out how to shut the MC media window.

This is now a really excellent solution. Thank you again!

[jmone]

Thanks !

So can I remove this part of the script do you think?

- Pressing "0" will check if the external player is running and if not run it again (in case it closes / crashes)

[jmone]

....also the team over at Cyberlink have been pretty good and after a bit of back and forward they are now looking at how to support MVC in MKV.  No timeline or promises yet but this would give a one player option for both 3D BD and 3D BD rips in MKV.

[TorqW]

Kudos to Cyberlink if they make that happen. That (plus your script) would basically mean PDVD becoming THE default player for most JRiver users.

As you say, ideally if the Dev team can create an option to toggle on/off whether jriver reacts to remote control commands that would be ideal too.

As regards leaving the "0" button functionality, I think you can remove it. But it would be great to have that version still available in case.

Excellent job sir!

[TorqW]

Hi Nathan,

Have had a chance to play around properly with everything with interesting results.

I think we should switch to using the classic mode of PowerDVD if possible, as it just seems more stable: on one of my set ups PDVDLP quits to a main menu randomly,
Furthermore the classic player offers much more control/options, i.e.:
- can access de-interlacing options
- audio sync delay options also available

I've tried modifying the script changing the switch from "PowerDVDCinema" to "PowerDVD" to invoke the classic mode, but this doesn't seem to work as it opens other windows saying that PowerDVD is already running.

Would you be able to take a look?

Thanks again!

[jmone]

Sure - I'll have a look but probably can't get to it till the end of the week though from memory there was some issue with Classic vs Cinema mode

[TorqW]

Look forward to seeing what you come up with.

I also tried opening the powerdvd.exe file directly but it would lose focus to another window opening and telling me powerdvd was already open.

Thanks again.

[jmone]

I'll probably add it as another player option, so you could have PDVD and PDVDC for example.